PCNこどもプロコン2015夏で入賞を逃した、地中脱出ゲームのKidsPod;バージョンです。
左上にあるのはポイントです。
1秒ごとに5ポイントずつ増えます。

パソコンではカーソルキー、
スマホでは下にあるボタンで操作します。

アイテム一覧

$袋:10ポイント増えます
毒:10秒間ジャンプ力が減ります(紫になります)
パン:10秒間ジャンプ力が増えます(ピンクになります)
イチゴ:5秒間ポイントが大量に増えます(黄色になります)


PCNこどもプロコン2015夏に応募し、何の賞にも入らなかったプログラムです。
上から次々と岩が落ちてくるので、それに乗り移って地上を目指します。
スペースキー(ジャンプ)と左右キー(横移動)で操作します。
左上に表示されているのは、地上までの距離です。
0m地点がゴールになります。
最初は岩の幅が3マス分ありますが、途中から2マス分になるので、気をつけて下さい。

バージョン IchigoJamBASIC1.1b9
プログラム


今日はこどもプロコン2015夏の審査会がありました。
めがね会館賞(サウンドバウンド)と3連続の最優秀賞(化石レーダー)を受賞しました!

商品は...



IchigoJam、PanCakeスターターキット組立版、
漆塗りケース、と盛り沢山!

おかげさまで受賞することができました。
これからもMASAHARUの魂のプログラム、応援よろしくお願いします。


ハッピーデモンストレーション、略してハピデモ!
誕生日はもちろん、何かとおめでたい時やデモ画面にも使えます。

最初のゴミはランダム表示です。
「HAPPY」にかぶらないように制限をかけています。
SCRを使って「HAPPY」を残したまま塗りつぶしています。
そのあとは繰り返しになります。



イチゴを別のキャラクターなどにして楽しむのもいいかもしれないです。

15 CLS:CLV
18 CLT
19 A=RND(31):B=RND(7)+8:IF SCR(A,B)=0 LCA,B:?CHR$(1):ELSE IF TICK()<500 GOTO19:ELSE GOTO 80
20 LC1,9:?" ":LC5,9:?" ":LC9,9:?" ":LC13,9:?"    ":LC19,9:?"    ":LC25,9:?" ":LC29,9:?" "
30 LC1,10:?" ":LC5,10:?" ":LC8,10:?" ":LC10,10:?" ":LC13,10:?" ":LC17,10:?" ":LC19,10:?" ":LC23,10:?" ":LC26,10:?" ":LC28,10:?" "
40 LC1,11:?"     ":LC8,11:?"   ":LC13,11:?"    ":LC19,11:?"    ":LC27,11:?" "
50 LC1,12:?" ":LC5,12:?" ":LC7,12:?" ":LC11,12:?" ":LC13,12:?" ":LC19,12:?" ":LC27,12:?" "
60 LC1,13:?" ":LC5,13:?" ":LC7,13:?" ":LC11,13:?" ":LC13,13:?" ":LC19,13:?" ":LC27,13:?" "
70 GOTO18
80 C=255
85 X=0:Y=8
90 IF (SCR(X,Y)=1)+(SCR(X,Y)=255) LCX,Y:?CHR$(C)
100 X=X+1:IF X=31 X=0:Y=Y+1:IF Y=15 GOTO120
110 GOTO 90
120 IF C=255 WAIT 300:C=1:GOTO85
130 WAIT 300:GOTO15


前回のパンケーキキャッチを改善しました。
改善点は
・落ちる速度が変わる
・たまにゆらゆらになる
・スコア表示桁数が3つ
・落ちてくるパンケーキの数が2つ
です。

プログラムも、バイナリコマンドを使ってスロット2つに収めました。

プログラム

スロット0
10 CLV:?"PC SPRITE START 05":A=RND(70):B=RND(70):D=RND(35)*-1:E=RND(35)*-1:X=34:N=0:P=166:Q=P:W=P:V=0
20 ?"PC SPRITE CREATE 0";N;" 7E":N=N+1:GSB 2000:IF N<=2 GOTO 20
35 ?"PC SPRITE CREATE 03 08"
60 ?"PC SPRITE CREATE 02 ";:M=Q:GSB1000:?
65 ?"PC SPRITE CREATE 04 ";:M=P:GSB1000:?
66 ?"PC SPRITE CREATE 09 ";:M=W:GSB1000:?
70 LRUN1                   <----次のプログラムをスロット1に保存した場合
980 IFN<10?N;:RTN
990 ?CHR$(N+55);:RTN
1000 N=M>>4:GSB980:N=M&15:GSB980:RTN
2000 H=RND(3):IF RND(2)=0 V=-1:RTN:ELSE RTN

スロット1
40 ?"PC SPRITE MOVE 00 ";:M=A:GSB1000:?" ";:M=D:GSB1000:?
50 ?"PC SPRITE MOVE 01 ";:M=B:GSB1000:?" ";:M=E:GSB1000:?
60 ?"PC SPRITE CREATE 02 ";HEX$(Q)
65 ?"PC SPRITE CREATE 04 ";HEX$(P)
66 ?"PC SPRITE CREATE 09 ";HEX$(W)
67 ?CHR$(#80,#6,#8,4,#10,#0)
68 ?CHR$(#80,#6,#8,2,#8,#0)
70 ?"PC SPRITE MOVE 03 ";:M=X:GSB1000:?" 23"
80 D=D+1+H:E=E+1+H:A=A+V*3:B=B+V*3:V=V*-1
90 IFD>44D=RND(35)*-1:A=RND(70):GSB2000
100 IFE>44E=RND(35)*-1:B=RND(70)
120 IF(D>25)*(A>X-7)*(A<X+7)?"PC SPRITE MOVE ";:M=D:N=A:GSB1100:D=M:A=N:GSB1000:?" ";:M=A:GSB1000:?:GSB2000:?"PC MUSIC SCORE 00 01 30 G>C":P=P+1:IFP=176P=166:Q=Q+1:IFQ=176Q=166:W=W+1
130 IF(E>25)*(B>X-7)*(B<X+7)?"PC SPRITE MOVE ";:M=E:N=B:GSB1100:E=M:B=N:GSB1000:?" ";:M=B:GSB1000:?:GSB2000:?"PC MUSIC SCORE 00 01 30 G>C":P=P+1:IFP=176P=166:Q=Q+1:IFQ=176Q=166:W=W+1
150 K=INKEY()
160 X=X-((K=28)*3)+((K=29)*3)
970 GOTO40
980 IFN<10?N;:RTN
990 ?CHR$(N+55);:RTN
1000 N=M>>4:GSB980:N=M&15:GSB980:RTN
1100 M=RND(35)*-1:N=RND(70):RTN
PanCake(4号)により、
IchigoJamU(8号)がついに3階建てになりました!



1階:IchigoJamU
2階:IchigoJamU専用シールド
3階:PanCake!!

横から見るとこんな感じです。(首里城みたい)
刺し心地もいい感じです。



IchigoJam,PanCakeを使ったプログラムです。
3つの音が壁に当たると、その音が出ます。
面白いリズムを楽しんで下さい。



バージョン:IchigoJam1.0.0b14

スロットを2つ使っています。
間違えないようにして下さい。

プログラム

スロット1

10 CLV:?"PANCAKE SPRITE START 01":A=RND(7)+82:B=RND(7)+82:C=RND(7)+82:D=RND(4):E=RND(4):F=RND(4):Z=0
20 IF A>86 A=A-7
30 IF B>86 B=B-7
40 IF C>86 C=C-7
50 ? "PANCAKE SPRITE CREATE 00 ";A:? "PANCAKE SPRITE CREATE 01 ";B:? "PANCAKE SPRITE CREATE 02 ";C
60 ? "PANCAKE SPRITE MOVE 00 ";:M=RND(60):G=M:GOSUB 1000:?" ";:M=RND(35):H=M:GOSUB 1000:?
70 ? "PANCAKE SPRITE MOVE 01 ";:M=RND(60):I=M:GOSUB 1000:?" ";:M=RND(35):J=M:GOSUB 1000:?
80 ? "PANCAKE SPRITE MOVE 02 ";:M=RND(60):K=M:GOSUB 1000:?" ";:M=RND(35):L=M:GOSUB 1000:?
120 LRUN 2 ←←←←←ここスロットによって変えてください。←←←←←
980 IF N<10 ?N;:RETURN
990 ?CHR$(N+55);:RETURN
1000 N=M>>4:GOSUB 980:N=M&15:GOSUB 980:RETURN


スロット2

60 ? "PANCAKE SPRITE MOVE 00 ";:M=G:GOSUB 1000:?" ";:M=H:GOSUB 1000:?
70 ? "PANCAKE SPRITE MOVE 01 ";:M=I:GOSUB 1000:?" ";:M=J:GOSUB 1000:?
80 ? "PANCAKE SPRITE MOVE 02 ";:M=K:GOSUB 1000:?" ";:M=L:GOSUB 1000:?
90 M=G:O=H:N=D:Q=A:GOSUB 500:G=M:H=O:D=N
100 M=I:O=J:N=E:Q=B:GOSUB 500:I=M:J=O:E=N
110 M=K:O=L:N=F:Q=C:GOSUB 500:K=M:L=O:F=N
120 GOTO 60
500 IF N=0 M=M-3:O=O-3:IF M<1 N=1:?"PANCAKE MUSIC SCORE 00 01 10 ";CHR$(Q-15):ELSE IF O<1 N=3:GOSUB 1100
510 IF N=1 M=M+3:O=O-3:IF M>69 N=0:?"PANCAKE MUSIC SCORE 00 01 10 ";CHR$(Q-15):ELSE IF O<1 N=2:GOSUB 1100
520 IF N=2 M=M+3:O=O+3:IF M>69 N=3:?"PANCAKE MUSIC SCORE 00 01 10 ";CHR$(Q-15):ELSE IF O>34 N=1:GOSUB 1100
530 IF N=3 M=M-3:O=O+3:IF M<1 N=2:?"PANCAKE MUSIC SCORE 00 01 10 ";CHR$(Q-15):ELSE IF O>34 N=0:GOSUB 1100
540 RETURN
970 END
980 IF N<10 ?N;:RETURN
990 ?CHR$(N+55);:RETURN
1000 N=M>>4:GOSUB 980:N=M&15:GOSUB 980:RETURN
1100 ?"PANCAKE MUSIC SCORE 00 01 10 ";CHR$(Q-15):RETURN


IchigoJam,PanCakeを使ったプログラムです。
上からどんどん落ちてくるパンケーキをキャッチするゲームです。



カウンターは99ポイントを越えるとバグります。
ご了承下さい。

バージョン:IchigoJam1.0.0b14

プログラム

10 CLV:?"PANCAKE SPRITE START 05":A=RND(70):D=RND(35)*-1:X=34:N=0:P=166:Q=166
20 ?"PANCAKE SPRITE CREATE 0";N;" 7E":N=N+1:IFN!=1GOTO20
35 ?"PANCAKE SPRITE CREATE 03 08"
40 ?"PANCAKE SPRITE MOVE 00 ";:M=A:GOSUB1000:?" ";:M=D:GOSUB1000:?
60 ?"PANCAKE SPRITE CREATE 02 ";:M=Q:GOSUB1000:?
65 ?"PANCAKE SPRITE CREATE 04 ";:M=P:GOSUB1000:?
66 ?"PANCAKE SPRITE MOVE 04 08 00"
67 ?"PANCAKE SPRITE MOVE 02 00 00"
70 ?"PANCAKE SPRITE MOVE 03 ";:M=X:GOSUB1000:?" 23"
80 D=D+1:E=E+1
90 IFD=45D=RND(35)*-1:A=RND(70)
120 IF(D=26)*((A>X-7)*(A<X+7))?"PANCAKE SPRITE MOVE ";:M=D:N=A:GOSUB1100:D=M:A=N:M=D:GOSUB1000:?" ";:M=A:GOSUB1000:?:?"PANCAKE MUSIC SCORE 00 01 30 G>C":P=P+1:IF P=176 P=166:Q=Q+1
150 K=INKEY()
160 X=X-((K=28)*3)+((K=29)*(3))
970 GOTO 40
980 IFN<10?N;:RETURN
990 ?CHR$(N+55);:RETURN
1000 N=M>>4:GOSUB980:N=M&15:GOSUB980:RETURN
1100 M=RND(35)*-1:N=RND(70):RETURN
IchigoDotの2号機をGETしたのでつくってみました。

半田付け中


Uさんにアドバイスを頂き、IchigoDotのバージョンアップ、マトリックスLEDの上下の向きを修正し、完成。

おまけ?の8×8ドットマンもきれいに映りました。


これもおまけ?おみくじ("みくじ"と表示されています)


大吉はこんな感じ(大古みたい)


電子工作マガジンのベーシックマガジンコーナーに、僕が作った「化石レーダー」が掲載されました。
コーナー初の掲載、嬉しいです!!!
さらに、「ブロック崩し」改良版の改造版も掲載されました。